In search for the fastest string concatenation method in LotusScript

Tommy Valand already published some test results from adding 100.000 times the word 'test':

• Using the StringBuffer class from Julian Robichaux: 0.25s
• Using NotesRichTextItem.appendText: 1.6s
• Using String concatenations (& or +): 140s

My test

I've done my own test with 10.000 iterations, adding one paragraph of Lorem Ipsum. Never try this at home, folks: I killed the server with it, so I had to reduce the number of iterations using simple string concatenations. Instead of Julians StringBuffer, I've tested my own. The total text size after concatenation was 4,3 mB.

The code

Sub Initialize
    
    Dim start As Long
    Dim s As New notessession
    Dim doc As NotesDocument
    Dim out As New stringbuffer(10)
    Dim max As Long, i As Long, sTmp As String
    Dim theSize As Long
    Dim theTime As Double
    
    Set doc=s.DocumentContext
    max=10000
    On Error Goto catch
    
' String concatenation
' Don't try this at home: with 10.000 iterations the server simply crashes
' So I do just a 1000 here to get an average idea
    start=Getthreadinfo(6)
    For i=0 To 1000
        sTmp=sTmp & SAMPLETEXT
    Next
    theTime=10*((Getthreadinfo(6)-start)/Getthreadinfo(7))
    out.add "<p>String concatenation: " & Format(theTime, "0.000") & " sec.</p>"
    
' StringBuffer
    start=Getthreadinfo(6)
    Dim tmp As New stringbuffer(1000)
    For i=0 To max
        tmp.add SAMPLETEXT
    Next
    sTmp=tmp.collapse("")
    theTime=(Getthreadinfo(6)-start)/Getthreadinfo(7)
    out.add "<p>StringBuffer class: " & Format(theTime, "0.000") & " sec.</p>"
    
' RichText item
' http://dontpanic82.blogspot.com/2007/10/thinking-outside-box-string.html
    Dim tmpDoc As notesdocument
    Dim rtItem As NotesRichTextItem
    
    Set tmpDoc=s.CurrentDatabase.CreateDocument
    Set rtItem=tmpDoc.CreateRichTextItem("Body")    
    For i=0 To max
        rtItem.AppendText SAMPLETEXT
    Next
    sTmp=rtItem.GetUnformattedText
    theTime=(Getthreadinfo(6)-start)/Getthreadinfo(7)
    out.add "<p>RichText item: " & Format(theTime, "0.000") & " sec.</p>"
    
' NotesStream
    start=Getthreadinfo(6)
    Dim tmp2 As NotesStream
    Set tmp2=s.CreateStream
    For i=0 To max
        tmp2.WriteText SAMPLETEXT
    Next
    tmp2.Position=0
    sTmp=tmp2.ReadText
    theTime=(Getthreadinfo(6)-start)/Getthreadinfo(7)
    out.add "<p>NotesStream: " & Format(theTime, "0.000") & " sec.</p>"
    
'finish it off
    Dim x
    x=Len(sTmp)/1024
    x=x/1024
    out.add "<p>Text size was: " & Format(x, "0.0") & " mB.</p>"
    
    doc.ReplaceItemValue "HtmlContent", out.collapse(NEWLINE)
    Goto finally
catch:
    doc.ReplaceItemValue "HtmlContent", "Error " & Err & " in line " & Erl & ": " & Error$
    Resume finally
finally:
End Sub

And the result

• String concatenation: 27,190 sec (stopped at 0.4 mB).
• StringBuffer class: 0,172 sec.
• RichText item: 0,922 sec.
• NotesStream: 0,672 sec.

The conclusion

When you want to add lots of strings together, always use the StringBuffer method.

Download

speedtest.zip (22 kB)