Notes Rich Text to XHTML: the code

¡Ay, caramba! In my previous post, I talked about finding the Philosopers stone: converting Notes Rich Text files into valid XHTML. The stone turned out to be a mountain. But here's a solution. It is based on a script from Julian Robichaux, but my version probably works for Notes 6.5 or higher only.

How it works

To get the HTML from a Notes RichText field, you have to copy it in another RichText field with the setting: Store contents as HTML and MIME:

I first tried to work directly on a field with this setting as does the IBM blog, but I noticed that in my case, the content of the field itself changed every time I edited it: line breaks were added, table information was lost, etc.

So I went for the same solution as Julian Robichaux and BlogSphere: creating a separate document with a copy of the RichText field and shaking it about until it spitted out the required HTML.

This separate document serves later also as a ghost document to retrieve the inline images. I didn't find another way to do it.

The Form code

All the code is in a LotusScript library, which you have to include in the (Globals)Document Options of the form:

Option Public
Option Declare
Use "HtmlEngine"

The conversion itself is triggered in the Document PostSave event:

Sub PostSave(Source As Notesuidocument)
    Dim s As New NotesSession
    Dim thisdb As NotesDatabase
    Dim thisdoc As NotesDocument
    Dim html As String
    
    Set thisdb = s.CurrentDatabase
    Set thisdoc = source.Document
    
    html=convertRichText(thisDoc,"Body",source.FieldGetText("DbPath"))
    Call thisDoc.ReplaceItemValue("HtmlBody",html)
    
    Call thisDoc.Save(True,True)
    Call source.Reload
    
End Sub

The transformation script

The function convertRichText in the HtmlEngine library first copies the field in the convert document. Next it gets the HTML from, and then it converts the image tags.

Function convertRichText(doc As NotesDocument, Byval fieldName As String,Byval dbPath As String) As String
    On Error Goto catch
    Dim session As New NotesSession
    Dim mText As String
    Dim db As NotesDatabase
    Dim newDoc As NotesDocument
    Dim noteID As String
    Dim currentSessionMimeSetting As Integer
    Dim rtitem As NotesRichTextItem
    Dim rtitem2 As NotesRichTextItem
    Dim docItem As NotesItem
    Dim mimeItem As NotesItem
    Dim mime As NotesMIMEEntity
    Dim child As NotesMIMEEntity
    Dim imgTag As String
    Dim altTag As String
    Dim imgCount As Integer
    Dim x As Integer
    Dim y As Integer
    Dim z As Integer
    
    Set rtitem=doc.GetFirstItem(fieldName)
    If (rtitem Is Nothing) Then
        Exit Function
    End If
    
' Get the convert document or create a new one if necessary
    currentSessionMimeSetting = session.ConvertMime
    session.ConvertMime=True
    Set db = session.CurrentDatabase
    If doc.MimeDocId(0)>"" Then
        Set newDoc=db.GetDocumentByid(doc.MimeDocId(0) & "")        
    End If
    If newDoc Is Nothing Then
        Set newDoc=New NotesDocument(db)
        newDoc.Form=CONVERTMIMEFORM
    Else
        While newDoc.HasItem(FieldName)
            newDoc.RemoveItem(FieldName)
        Wend
    End If
    newDoc.subject=doc.subject(0) & " - images"
    Set rtitem2=New NotesRichTextItem(newDoc, FieldName)
    Call rtitem2.AppendRTItem(rtitem)
    Call newDoc.Save(True, True)
    noteId=RefreshDocFields(newDoc)
    doc.MimeDocId=noteId
    Set newDoc=Nothing
    
' Get the HTML
    session.ConvertMime=False
    Set newDoc=db.GetDocumentById(noteID)
    Set mimeItem=newDoc.GetFirstItem(FieldName)
    If Not (mimeItem Is Nothing) Then
        If (mimeItem.Type=MIME_PART) Then
            Set mime=mimeItem.GetMimeEntity
            If Not (mime Is Nothing) Then
                Call mime.DecodeContent
                If (mime.ContentType="multipart") Then
                    Set child = mime.GetFirstChildEntity
                    While Not(child Is Nothing)
                        If child.ContentSubType="html" Then
                            Call child.DecodeContent
                            mText = mText & child.ContentAsText
                        End If
                        Set child=child.GetNextEntity(1724)
                    Wend
                Else
                    mText=mText & mime.ContentAsText
                End If
            End If
        End If
    End If
    session.ConvertMIME=currentSessionMimeSetting
    
'Converting the image tags
    imgCount=1
    x = Instr(1,mText,"<img src=cid:")
    While x<>0
        imgCount=imgCount +1
        y=Instr(x,mText,">")
        z=Instr(x, mText, | alt=|) +5
        If z>5 And z<y Then
            altTag=|"|+Mid$(mText, z, y-z)+|"|
        Else
            altTag=|"M| + Cstr(imgCount) +|"|
        End If
        altTag=Replace(altTag, |""|, |"|)
        imgTag = |<img src="|+dbPath+|0/|+newDoc.universalId+|/|+ fieldName +|/M| + Cstr(imgCount) + |?OpenElement"|
        mText = Left(mText,x-1) + imgTag + | alt=| + altTag + | />| + Right(mText,Len(mText)-(y))
        x = Instr(1,mText,|<img src=cid:|)
    Wend
    mText=htmlTidy(mText)
    
    Goto finally
catch:
    Msgbox "Error " & Err & " in line " & Erl & ": " & Error$
    Resume finally
finally:
    ConvertRichText=mText
End Function

Tidying up the HTML to get valid XHTML

Based on what I found in BlogSphere and the IBM blog template, here's what I brewed to transform the HTML4 to valid XHTML:

(see the sample db in the zip file)

The result

This is the output of my test page. All valid XHTML. BTW: you have to scroll a very long way to get to the download, haven't you?

But here's the download. Use at your own risk. Don't come asking if something does not work.

Download

notesrichtext-to-html.zip (75 kB)